Groovy Fizz and Buzz

fred@fredjean.net (Frederic Jean) — Thu, 28 Feb 2008 06:57:02 +0000

The FizzBuzz programming interview question raised it's head again. I've managed to resist the temptation to implement it in any languages so far. Until this morning that is...

So I fired up the Groovy Console and played a little. A nice feature of the console is that it displays a history of the scripts it ran. This allows me to present an evolution of my FizzBuzz program.

I first started with a rather naive implementation:

(1..100).each { 
  def out = "" 
  if ((it % 3) == 0) { out += "Fizz" } 
  if ((it % 5) == 0) { out += "Buzz" } 
  if (out == "" ) { out = it } 
  println out
}

Not bad for something that I came up with in about 10 minutes. It doesn't really take advantage of Groovy's features though. So I refined it a bit by using the ternary operator:

(1..100).each {
  def out = (it % 3) == 0 ? "Fizz" : ""
  out += (it % 5) == 0 ? "Buzz" : ""
  println (out == "" ? it : out)
}

This is a slight improvement over the first version. I still didn't feel that this was Groovy enough for me. I decided to play with the List collect method. This applies a closure to all items in a collection. The first pass was the following code segment:

println ((1..100).collect {
  def out = (it % 3) == 0 ? "Fizz" : ""
  out += (it % 5) == 0 ? "Buzz" : ""
  out == "" ? it : out
})

This ended up printing the list returned by the collect method. Really close, but not quite what I was hoping for. After all, the challenge is to print the results, not quite a string representation of a list. It was easy then to go from the code above to the code below:

(1..100).collect {
  def out = (it % 3) == 0 ? "Fizz" : ""
  out += (it % 5) == 0 ? "Buzz" : ""
  out ?: it
}.each { println it }

This printed the list just like the first pass. It's definitively Groovier (in my opinion) than the original implementation. It still does fall short of the capabilities of Groovy.

So here's my final implementation:

(1..100).collect {
     ((it % 3) == 0 ? "Fizz" : "") << ((it % 5) == 0 ? "Buzz" : "") ?: it
}.each { println it }

This takes full advantage of Groovy's power. It is a little harder to read, which is a downside. It does take full advantage of many of Groovy's powerful features:

A range to generate the list of numbers to process. Ranges return an iterator that iterates from the start of the range to the end of the range.
The collect method which applies a closure to each item in the collection (or iterator) and returns the results as a list.
The each method, which iterates through a list and applies a closure to it. It returns the collection that it iterated through.
Closures, which are implemented quite well in Groovy.
Operator overloading. The << operator is overloaded on the String class to concatenate two Strings together.
The brand new Elvis operator (?:) which returns the alternate value if the expression evaluates to false.
Groovy returns the last expression of a block as the result of the block. This includes closures and methods.

I do think that I'll incorporate this question in future interviews. It has quite a few interesting subtleties and implementations that are only rivaled by the Singleton pattern. I guess that the last group of interviewees got it a little easier...

"Groovy Fizz and Buzz" by Tim Yates

Fri, 29 Feb 2008 13:21:18 +0000

Sorry...me again... For completeness (and full Groovy-ness), I did it using Categories ;)

class FizzCategory {
  static Object fizz( Integer i ) {
    ( i % 3 ? "" : "Fizz" ) << ( i % 5 ? "" : "Buzz" ) ?: i
  }
}
use( FizzCategory ) {
  (1..100)*.fizz().each { println it }
}

"Groovy Fizz and Buzz" by Jason S

Thu, 28 Feb 2008 23:51:02 +0000

This is less groovy but pretty short: (1..100).each{s=(it%3?"":"fizz")+(it%5?"":"buzz");println s==""?it:s}

"Groovy Fizz and Buzz" by Frederic Jean

Thu, 28 Feb 2008 14:54:00 +0000

Tim,

Now I'm having the d'oh! moment ;). I didn't think about extending the Integer class. Very nice implementation.

Fred

"Groovy Fizz and Buzz" by Tim Yates

Thu, 28 Feb 2008 14:13:33 +0000

I'm an idiot... *blush*

Integer.metaClass.fizz = { ->
  ( delegate % 3 ? "" : "Fizz" ) << ( delegate % 5 ? "" : "Buzz" ) ?: delegate
}
(1..100)*.fizz().each { println it }

That's it...I promise...

"Groovy Fizz and Buzz" by Tim Yates

Thu, 28 Feb 2008 13:35:34 +0000

Sorry...me again... I got carried away...

Integer.metaClass.fizzbuzz = { ->
  def r
  delegate.each { 
    r = ( it % 3 ? "" : "Fizz" ) << ( it % 5 ? "" : "Buzz" ) ?: it
  }
  r
}
(1..100)*.fizzbuzz().each { println it }

"Groovy Fizz and Buzz" by Tim Yates

Thu, 28 Feb 2008 10:05:04 +0000

Or, as Groovy allows conditionals in a C style, the following works as well...

(1..100).collect {
  ( it % 3 ? "" : "Fizz" ) << ( it % 5 ? "" : "Buzz" ) ?: it
}.each { println it }

Maybe even less readable, but less code also ;)

Out of my mind...: Groovy Fizz and Buzz

Groovy Fizz and Buzz

"Groovy Fizz and Buzz" by Tim Yates

"Groovy Fizz and Buzz" by Jason S

"Groovy Fizz and Buzz" by Frederic Jean

"Groovy Fizz and Buzz" by Tim Yates

"Groovy Fizz and Buzz" by Tim Yates

"Groovy Fizz and Buzz" by Tim Yates